GOOGLEFINANCE 함수 – 주식, 환율, 암호화폐 조회

구글시트에서만 가능한 GOOGLEFINANCE 함수를 사용하면 주식 시세 조회, 환율 조회, 암호화폐 시세조회 등 많은 일을 할 수 있습니다.

구문(Syntax)

 

주식 시세 조회

ticker를 입력하여 주식 시세를 조회할 수 있습니다. 최대 20분 지연된 시세입니다.

현대차 현재가 조회

=GOOGLEFINANCE("KRX:005380") → 206,000 원

첫 번째 인수로 "KRX:005380"을 입력합니다. 종목코드만 입력해도 되지만 정확한 검색을 위해 거래소코드를 앞에 붙인 "KRX:005380" 형태로 입력하는 것이 안전합니다.

 

 미국 주식 Apple 현재가 조회

=GOOGLEFINANCE("NASDAQ:AAPL") → 236 USD

 

현대차 과거 주가 조회(2025-01-02 종가)

=GOOGLEFINANCE("KRX:005380","close","2025-01-02")

과거 데이터는 배열 형태로 조회됩니다.

 

현대차 과거 주가에서 날짜 제외하고 종가만 조회

=INDEX(GOOGLEFINANCE("KRX:005380","close","2025-01-02"),2,2) → 211,500 원

과거 데이터는 배열 형태로 조회되므로 INDEX 함수로 1월 2일에 해당하는 부분만 추출합니다. 배열의 2행 2열에 1월 2일 종가가 있으므로 INDEX함수의 두 번째 인수에 2, 세 번째 인수에 2를 입력합니다.

※ 구글시트의 INDEX 함수는 엑셀의 INDEX 함수와 사용법이 동일하므로 여기를 클릭하여 참고합니다.

 

INDEX 함수로 GOOGLEFINANCE("KRX:005380","close","2025-01-02")의 결과에서 2행 2열을 추출하면 다음과 같이 종가만 추출됩니다.

 

현대차 과거 주가 조회(2025-01-02 모든 수치)

=GOOGLEFINANCE("KRX:005380","all","2025-01-02","2025-01-02")

두 번째 인수 attribute에 "all"을 입력하면 주식의 시가,고가,저가,종가,거래량을 조회할 수 있습니다.

 

 

기간별 주식 시세 조회

기간(start_date, end_date)을 입력하여 기간별 주식 시세를 조회할 수 있습니다.

현대차 2025-01-02 ~ 2025-01-07 기간의 일별 종가

=GOOGLEFINANCE("KRX:005380","close","2025-01-02","2025-01-07","DAILY")

2025-01-02 ~ 2025-01-07 기간의 일별 종가를 조회합니다.

인수 설명:

• ticker: "KRX:005380" (현대차)
• attribute: "close" (종가)
• start_date: "2025-01-02"
• end_date: "2025-01-07"
• interval: "DAILY" (일자별 조회)

 

현대차 2025-01-02 ~ 2025-01-31 기간의 주별 종가

=GOOGLEFINANCE("KRX:005380","close","2025-01-02","2025-01-31","WEEKLY")

2025-01-02 ~ 2025-01-31 기간의 주별 종가를 조회합니다.

인수 설명:

• ticker: "KRX:005380" (현대차)
• attribute: "close" (종가)
• start_date: "2025-01-02"
• end_date: "2025-01-31"
• interval: "WEEKLY" (주별 조회)

 

 

지수 조회

KOSPI, S&P500, NASDAQ 등 각종 금융 지수를 조회할 수 있습니다.

코스피(KOSPI) 현재 지수 조회

=GOOGLEFINANCE("KRX:KOSPI")

 

코스피(KOSPI) 지수 일별 종가 조회

=GOOGLEFINANCE("KRX:KOSPI","close","2025-01-02","2025-01-10","DAILY")

2025-01-02 ~ 2025-01-10 기간의 코스피 지수 일별 종가를 조회합니다.

 

해외 지수 조회

S&P500, NASDAQ, DOW 지수 조회

S&P500: =GOOGLEFINANCE("INDEXSP:.INX")
NASDAQ: =GOOGLEFINANCE("INDEXNASDAQ:.IXIC")
DOW: =GOOGLEFINANCE("INDEXDJX:.DJI")

 

S&P500 지수 주별 종가 조회

=GOOGLEFINANCE("INDEXSP:.INX","close","2025-01-02","2025-02-10","WEEKLY")

2025-01-02 ~ 2025-02-10 기간의 S&P500 지수 주별 종가를 조회합니다.

인수 설명:

• ticker: "INDEXSP:.INX" (S&P500 지수)
• attribute: "close" (종가)
• start_date: "2025-01-02"
• end_date: "2025-02-10"
• interval: "WEEKLY" (주별 조회)

 

 

환율 조회

통화별 환율을 조회할 수 있습니다.

ticker는 "CURRENCY:USDKRW" 형태로 입력합니다. 통화코드는 USDKRW와 같이 2개의 통화코드를 연속으로 입력합니다.

※ 환율은 구글 파이낸스 기준임, 국내 은행의 고시환율과 다를 수 있습니다.

현재 환율 조회

USD -> KRW: =GOOGLEFINANCE("CURRENCY:USDKRW")
EUR -> KRW: =GOOGLEFINANCE("CURRENCY:EURKRW")
JPY -> KRW: =GOOGLEFINANCE("CURRENCY:JPYKRW")

 

환율 추이(USD->KRW) 조회

=GOOGLEFINANCE("CURRENCY:USDKRW","price",today()-7,today(), "DAILY")

현재일부터 과거 7일 동안의 USD->KRW 환율을 조회합니다.

인수 설명:

• ticker: "CURRENCY:USDKRW" (USD->KRW 환율)
• attribute: "price"
• start_date: today()-7 (과거 7일)
• end_date: today() (현재일)
• interval: "DAILY" (일별 조회)

 

 

암호화폐 시세 조회

GOOGLEFINANCE 함수로 암호화폐 시세도 조회할 수 있습니다.

ticker는 "CURRENCY:BTCUSD" 형태로 입력합니다. 종목코드는 BTCUSD와 같이 '암호화폐코드, 통화코드'를 연속으로 입력합니다.

암호화폐 현재 시세 조회

비트코인(BTC -> USD): =GOOGLEFINANCE("CURRENCY:BTCUSD")
비트코인(BTC -> KRW): =GOOGLEFINANCE("CURRENCY:BTCKRW")
이더리움(ETH -> USD): =GOOGLEFINANCE("CURRENCY:ETHUSD")
이더리움(ETH -> KRW): =GOOGLEFINANCE("CURRENCY:ETHKRW")

 

비트코인 시세 추이 조회

=GOOGLEFINANCE("CURRENCY:BTCUSD","price",today()-7,today(), "DAILY")

현재일부터 과거 7일 동안의 비트코인의 미국달러(USD) 가격을 조회합니다.

 

 

기타 

GOOGLEFINANCE 함수 사용시 확인을 위해 ticker명이 필요할 때가 있습니다.

두 번째 인수에 "name"을 입력하면 됩니다. 국내 주식도 영어로만 조회되는 단점이 있습니다.

=GOOGLEFINANCE("KRX:005380","name") → Hyundai Motor Co
=GOOGLEFINANCE("NASDAQ:AAPL","name") → Apple Inc
=GOOGLEFINANCE("NASDAQ:GOOG","name") → Alphabet Inc Class C
=GOOGLEFINANCE("INDEXSP:.INX","name") → S&P 500

 

 

 

GOOGLEFINANCE 함수 사용 시 오류

GOOGLEFINANCE 함수를 잘못 사용할 경우 다음과 같은 오류가 발생할 수 있습니다.

#N/A: 종목코드를 잘못 입력한 경우

 

#N/A: 인수를 잘못 입력한 경우

과거 데이터 조회 시는 일자를 입력해야 하는데 일자가 누락되어 오류 발생

 

 

두 번째 인수: attribute(속성) 

Google Finance에서 ticker에 대해 가져올 속성이며 날짜가 지정된 경우 필수입니다.

실시간 데이터 속성

실시간인 경우 최대 20분 지연된 가격정보가 조회됩니다.

속성	설명	비고
price	실시간 가격 정보	기본값
priceopen	개장 시점의 가격
high	현재 날짜의 최고가
low	현재 날짜의 최저가
volume	현재 날짜의 거래량
marketcap	주식의 시가 총액
tradetime	마지막 거래 시간
datadelay	데이터의 지연 정도
volumeavg	일일 평균 거래량
pe	가격 대 수익률
eps	주당 순이익
high52	52주 최고가
low52	52주 최저가
change	전 거래일 마감 이후의 가격 변동
beta	베타 값
changepct	전 거래일 마감 이후 주식 가격의 백분율 변동
closeyest	전일 종가
shares	발행 주식 수
currency	유가증권이 거래되는 통화	open, low, high 또는 volume을 사용하면 결과가 반환되지 않음

 

과거 데이터 속성

속성	설명
open	지정한 날짜의 개장가
close	지정한 날짜의 종가
high	지정한 날짜의 최고가
low	지정한 날짜의 최저가
volume	지정한 날짜의 거래량
all	지정한 날짜의 모든 속성 (open, close, high, low, volume)

 

뮤추얼 펀드 데이터 속성

속성	설명	비고
closeyest	전일 종가
date	순 자산 가치가 보고된 날짜
returnytd	YTD(연간) 총 수익
netassets	순 자산
change	가장 최근에 기록한 순 자산 가치와 그 직전에 기록한 순 자산 가치 간의 값 변동
changepct	순 자산 가치의 백분율 변동
yieldpct	지난 12개월 동안 배분된 수입을 모두 합한 금액(주식 배당금과 고정 수입 이자 지급액)에 순 자산 가치 증가분을 더한 다음 전월 순 자산 가치로 나눈 배분율
returnday	1일 총 수익
return1	1주 총 수익
return4	4주 총 수익
return13	13주 총 수익
return52	52주(연간) 총 수익
return156	156주(3년) 총 수익
return260	260주(5년) 총 수익
incomedividend	최근 현금 배분액
incomedividenddate	최근 현금 배분 날짜
capitalgain	최근 자본 이득 배분액
morningstarrating	Morningstar의 'star' 등급
expenseratio	펀드의 비용 비율