엑셀 함수 > 통계 함수 > COUNTIFS 함수 - 여러 조건을 만족하는 셀의 개수 구하기

COUNTIFS 함수 - 여러 조건을 만족하는 셀의 개수 구하기

엑셀에서 COUNTIF 함수를 이용하면 한 번에 하나의 조건을 만족하는 셀의 개수를 구할 수 있지만, COUNTIFS 함수를 이용하면 여러 개의 조건을 만족하는 셀의 개수를 구할 수 있습니다.

COUNTIFS는 COUNTIF 함수의 IF에 S가 붙은 형태입니다. S는 영어에서 복수형일 때 붙으므로 IF가 여러 개 있는... 즉 조건을 여러 개 정해서 셀의 개수를 구하는 함수라고 생각하면 됩니다.

COUNTIF 함수가 궁금할땐 여기를 클릭!

※ COUNTIFS는 어떻게 발음해야 할까요? 마이크로소트프 홈페이지 동영상 강의를 보면 “카운트이프스”라고 하는데 우리나라 사람들은 “카운트이프에스”라고도 많이 부릅니다.

구문(Syntax)

COUNTIFS

COUNTIFS(criteria_range1, criteria1, [criteria_range2, criteria2], …)

COUNTIFS(조건범위1, 조건1, [조건범위2, 조건2], …)

범위에서 여러 조건을 만족하는 셀의 개수를 구해준다.

인수 :

  • criteria_range1 : 첫번째 조건을 적용할 범위
  • criteria1 : 개수를 구할 첫번째 조건
  • criteria_range2 : 두번째 조건을 적용할 범위
  • criteria2 : 개수를 구할 두번째 조건

criteria_range, criteria 는 최대 127개까지 지정할 수 있다.

 

사용 예

1) 특정 조건을 만족하는 셀의 개수 구하기

아래 그림의 자료에서

  • 분류가 '노트류'이면서
  • 상품이 '스프링노트'인

것의 개수를 구하려면 다음과 같이 수식을 입력합니다.

=COUNTIFS(C5:C12,"노트류",D5:D12,"스프링노트")

COUNTIFS 함수로 조건을 만족하는 셀의 개수 구하기

 

함수의 인수를 살펴보면 다음과 같습니다

COUNTIFS 함수 인수 설명

 

수식을 정리해 보면 COUNTIFS함수는 아래 그림과 같이

  • 분류가 입력된 첫 번째 조건범위 [C5:C12]에서 값이 '노트류'이고
  • 상품이 입력된 두 번째 조건범위 [D5:D12]에서 값이 '스프링노트'인 것을

만족하는 행의 갯수 2를 구해줍니다.

COUNTIFS 함수로 조건을 만족하는 셀의 개수 구하기

 

2) 와일드카드 문자로 찾아서 조건을 만족하는 셀의 개수 구하기

이번에는

  • 분류가 '노트류'이면서
  • 상품 이름에  '스프링노트'가 포함된 것의 개수를 구해보겠습니다.

COUNTIFS 함수 - 와일드카드로 조건을 만족하는 셀의 개수 구하기

[B28] 셀에 다음 수식을 입력합니다.

=COUNTIFS(C19:C26,"노트류",D19:D26,"*스프링노트*")

*(별표)는 여러 문자를 대신하므로 '스프링노트'라는 문자열 앞뒤로 몇개의 문자열이 오든 상관없이 '스프링노트'라는 값을 포함한 셀은 개수에 포함됩니다.

분류가 노트류이고 상품이름에 '스프링노트'를 포함한 것은 스프링노트고급형 1개, 스프링노트 2개가 있으므로 COUNTIFS함수는 개수 3을 구해줍니다.

※ 참고 : 와일드카드 문자는 좀 더 정교한 방법으로 값을 찾을 때 사용하는데 다음 2가지가 있습니다.

  • ?(물음표) : 한 개의 임의의 문자열을 의미
  • *(별표) : 여러 개의 임의의 문자열을 의미

 

3) 숫자 조건을 만족하는 셀의 개수 구하기

이번에는 다음 표에서

  • 분류가 '노트류'이면서
  • 판매금액이 10만원 이상(10만원보다 크거나 같은)인 행의 갯수를 구해보겠습니다.

COUNTIFS 함수로 숫자 조건을 만족하는 셀의 개수 구하기

[B42] 셀에 다음 수식을 입력합니다.

=COUNTIFS(C33:C40,"노트류",G33:G40,">=100000")

위에서 분류가 '노트류'이고, 판매금액이 10만원 이상인 것은

  • 33행의 210,000원
  • 34행의 300,000원 이므로

위 수식은 개수 2을 구해줍니다.

※ 참고 : 위 수식에서 '>=' 연산자가 사용되었는데 특정 값보다 크거나 같은 것을 의미합니다.
연산자를 사용하면 다음과 같이 다양한 방법으로 숫자 조건을 설정할 수 있습니다.

  • =100 : 100인
  • <>100 : 100이 아닌
  • >100 : 100보다 큰
  • >=100 : 100보다 크거나 같은(100이상인)
  • <100 : 100보다 작은(100미만인)
  • <=100 : 100보다 작거나 같은

 

4) 다른 시트의 자료를 참조하여 참석자 수 집계

이번에는 실무에서 많이 사용하는 '다른 시트의 자료를 집계하는 방법'을 알아보겠습니다.

다음과 같이 교육 참석 현황 자료가 있을 때 이 자료에서 교육과정별, 참석 부서별 참석자 수를 집계해 보겠습니다.

집계용 기초 자료

 

<표 만들기>

교육과정명과 부서가 변경될 때 표에서 교육과정명과 부서명만 바꾸면, 바꾼이름으로 COUNTIFS 함수가 작동하도록 아래와 같이 표를 먼저 만듭니다.

COUNTIFS 함수로 집계하기 - 표 만들기

 

<수식 입력>

COUNTIFS 함수로 집계하기 - 수식 입력

  • 참석자수를 구하는 수식은 [E47]셀에 다음과 같이 입력
    =COUNTIFS(교육참석현황!$A$2:$A$22,집계!B47,교육참석현황!$C$2:$C$22,집계!C47)
  • 불참자수는 정원에서 참석자수를 빼주도록 수식 입력
    =D47-E47
  • 마지막으로 [E47:F47]에 입력된 수식을 복사하여 [E48:F55]범위에 붙여 넣으면 집계표가 완성됩니다.

 

수식을 정리해 보면 COUNTIFS함수는 아래 그림과 같이

  • 1-1) 첫번째 조건범위인 교육참석현황 시트의 [$A$2:$A$22] 범위의 값이
  • 1-2) 집계 시트의 [B47]셀의 값과 같은 '직장내 성희롱 예방교육'이고
  • 2-1) 두번째 조건범위인 교육참석현황 시트의 [C$2:$C$22] 범위의 값이
  • 2-2) 집계 시트의 [C47]셀의 값과 같은 '인사팀'인 것을

만족하는 행의 갯수 3을 구해줍니다.

COUNTIFS 함수로 집계하기

 

 

 


관련 글

DCOUNTA 함수 - 데이터베이스에서 비어 있지 않은 셀의 개수 구하기 - 엑셀의 데이터베이스(Database)함수는 다양한 조건에 맞는 합계를 구한다던지, 평균, 갯수 등을 쉽게 구할 수 있는 함수이다. 모든 데이터베이스 함수는 알파벳 “D”로…

DCOUNTA 함수 - 데이터베이스에서 비어 있지 않은 셀의 개수 구하기 더 보기 »

DCOUNT 함수 - 데이터베이스에서 숫자가 포함된 셀의 개수 구하기 - 엑셀의 데이터베이스(Database)함수는 다양한 조건에 맞는 합계를 구한다던지, 평균, 갯수 등을 쉽게 구할 수 있는 함수이다. 모든 함수는 알파벳 “D”로 시작하며…

DCOUNT 함수 - 데이터베이스에서 숫자가 포함된 셀의 개수 구하기 더 보기 »

COUNT 함수 사용법 COUNT함수로 갯수 구하기 COUNT, COUNTA, COUNTBLANK - 엑셀 함수 중에서 다음과 같이 COUNT로 시작하는 함수가 있는데 이름에서 유추할 수 있듯이 개수를 구해주는 함수입니다. COUNT - 숫자의 개수를…

COUNT함수로 갯수 구하기 COUNT, COUNTA, COUNTBLANK 더 보기 »

COUNTIF 함수 사용법 COUNTIF 함수 - 조건을 만족하는 셀 개수 구하기 - 엑셀의 COUNTIF 함수는 COUNT와 IF가 합쳐진 형태로, 만약(IF) 어떤 조건을 만족하면 COUNT하라는 의미입니다. 특정 조건을 만족하는 셀의 개수를 구해야 할 때…

COUNTIF 함수 - 조건을 만족하는 셀 개수 구하기 더 보기 »

COUNTIFS 함수로 월별 개수 구하기 COUNTIFS 함수로 월별 개수 구하기 - 엑셀에서 COUNTIFS 함수를 이용하면 여러 개의 조건을 만족하는 셀의 개수를 구할 수 있는데, 월의 첫째날보다 크거나 같고 말일보다 작거나 같은…

COUNTIFS 함수로 월별 개수 구하기 더 보기 »

 

엑셀웍스 책 출간 안내

그동안 엑셀웍스에 올린 '엑셀 강좌', '함수 사용법', 여러 '실무 예제'에서 핵심만 뽑아 '된다! 엑셀 수식 & 함수' 책으로 출간하였습니다.

엑셀웍스 책 출간안내  자세히 보기

온라인 구매처: 예스24   교보문고   알라딘 

“COUNTIFS 함수 - 여러 조건을 만족하는 셀의 개수 구하기”의 46개의 댓글

  1. 카운트궁구미

    =COUNTIFS(C33:C40,”노트류”,G33:G40,”>=100000″)

    여기에서 ">=100000" 부분을
    수식을 이용한 계산값으로 넣을 수 없을 까요?

    예를 들면,
    =COUNTIFS(G30:G39,"노트류",E30:E39,>(edate(today(),-1)))
    노트류 인 셀 중 특정셀의 날짜가 오늘로부터 한달 이후인 경우 를 카운트하고 싶어요

    1. 안녕하세요. 다음과 같이 하시면 됩니다. 혹시 아래 수식을 복사해서 붙여 넣은 후 오류가 나면 쌍따옴표는 키보드에 있는 따옴표로 다시 입력해주세요.
      =COUNTIFS(C33:C40,"노트류",B33:B40,">" & (EDATE(TODAY(),-1)))
      감사합니다.

      1. 카운트궁구미

        말씀해주신대로 했더니 오류는 없는데,
        결과 값이 안나옵니다.

        (EDATE(TODAY(),-1))) 함수 값이 날짜가 아닌 숫자로 나와서 그러는 건지
        특정셀의 날짜로부터 오늘 날짜가 한달이 도과했는지를 알고 싶은 것인데
        혹시 방법이 있을까요?

        1. 안녕하세요. 어떻게 입력하신건지 봐야 알것 같습니다. 수식을 입력한 엑셀파일을 admin@xlworks.net으로 보내주시면 확인해 보겠습니다.

  2. 101에서 170까지의 중복값이 존재하는 셀에서

    중복되는 셀은 1개로 인식하여 개수를 구하는 함수가 있을까요?

    예시)
    셀의 개수 5개
    101,101,101,102,103,104,105

    1. 배열수식으로 해결해야 합니다.
      A1:A7의 범위에 101,101,101,102,103,104,105 이 입력되어 있다고 할때
      A8셀에 =SUM(1/COUNTIF(A1:A7,A1:A7))을 입력한 후 Enter를 대신 Ctrl+Shift+Enter를 누릅니다.
      위의 범위에서 countif함수로 각각의 셀에 해당하는 갯수가 몇개인를 구해서, 1을 그 갯수로 나눈 후 더하면 중복을 제외한 갯수가 나옵니다.(첫번째 셀은 101이 들어있고 101은 3개가 있으므로 3이 구해지고, 두번째,세번째 셀은 마찬가지로 3이 구해지고 1/3, 1/3, 1/3이 각각 구해지고 102부터는 중복이 없으므 1/1 이 구해지고 다 더하면 5가 됩니다)
      배열수식에 대한 설명은 다음 링크를 참고하세요.
      https://xlworks.net/excel_tutorial_intermediate_array_formula/

  3. 감사합니다

    안녕하세요 잘 사용하고 있습니다! 감사합니다!
    혹시 3) 숫자 조건을 만족하는 셀의 개수 구하기 여기서요.
    10만원보다 큰!이라는 조건을 100,000을 직접 쓰지 않고 특정 셀을 지정하면 값이 제대로 안나오네요.
    특정 셀에 100000을 넣어놓고, 수시로 변경하면서 쓰고싶어서 해보려고 했었습니다.

  4. 질문이요

    저 시트에 날짜를 기준 7월에 특정부서가 몇개를 들었는지 8월에 특정부서가 몇번을 들었는지 하는 카운트를 구하고싶으면 어떻게 해야하나요

  5. 안녕하세요..
    설명 너무 쉽게 잘 되어있어서 좋았습니다.
    다름이 아니라 저는 침구 렌탈 서비스를 하고 있는데
    이름만 적으면 이 고객이 제품, 사이즈, 색상, 수량이 나오게 하고 싶습니다.
    vlookup은 다수의 명령어를 못 끌어 오는거 같아서요..

    예를들면
    A열은 제품명(이불커버,매트커버,베개커버)
    B열은 색상(화이트,그레이)
    C열은 사이즈 S,SS,D,Q)
    D열은 오염,폐기
    F열은 고객명
    이렇게 나열이 되면 오염된건 폐기를 하고 다른 제품으로 교체를 해 줍니다.
    근데 이 자료가 밑으로 계속 누적이 되고 썻던 제품은 바코드를 찍기 때문에
    쌓여 있는거죠... 그러다 보니 홍길동이 어떤 제품이 몇개나 오염 됐는지 폐기 했는지
    모르겠더라구요.. 그래서 혹시나 이름만 치면 고객이 이 고객이 사용한 "오염" 에 해당하는
    제품들만 나오게 할 수 있을까요??

  6. 조서준

    =COUNTIFS(R:R,"A", P:P,"B, U:U,COUNTBLANK(U:U))

    위와같이 R열에 A,P열에 B가 입력되어 있으면서
    U열에는 공란일 경우 모든 조건을 원하는 개수를 찾고 싶은데요.

    U열이 빈칸일 경우 모든 조건을 만족하는 셀의 개수를 찾는 방법이 있을까요

    1. 다음 수식을 입력해보세요. 마지막 쌍따옴표 2개는 빈칸을 의미합니다
      =COUNTIFS(R:R,"A",P:P,"B",U:U,"")
      혹시 수식이 작동하지 않으면 쌍따옴표를 키보드에 있는 것으로 다시 입력해보세요.

  7. 글 잘 보았습니다. 질문이 있어요. countif함수 관련되어서요. 예를 들면 C4와 C20 두개의 셀이 같은 값 "1"을 가지고, 동시에 그외 다른 두개의 셀들도 "1"을 가진 경우 이들을 count를 하고 싶어서요.

    다시말해서, C4와 C20가 동시에 "1"을 가지고, C5와 C21도 "1"을 가지며, C6과 C22도 "1"을 가지고 그러나 C7과 C23은 하나의 셀만 "1"을 가진다면, 총 "1"을 세번 가지는 거잖아요... 이러한 패턴으로 "1"의 빈도수를 구하고 싶습니다.

    혹시 countif로 사용해야하는 것인지요? 아니면 다른 함수가 필요한가요? 선생님의 도움 받고 싶습니다! 감사합니다.

    1. 안녕하세요. 다음과 같이 하시면 될것 같습니다.
      =COUNTIFS(C4:C7,1,C20:C23,1)
      여러 개의 조건을 체크하므로 COUNTIF함수 대신 COUNTIFS함수를 사용하셔야 합니다.

  8. 노트가 판매된 날자
    특정 범위 셀에 입력된 데이터가 있는
    날자 를 따로검출해줄수는없을까요? ^^:
    =COUNTIFS(C5:C12,"노트류",D5:D12,"스프링노트")

    2021-05-11 노트 / 노트가 나온 셀의 좌측에 이는 날자 를 따로 검출하고 싶은데요 ^^:

    1. 아래와 같이 INDEX함수와 MATCH함수를 이용해서 다중조건으로 값을 찾으면 됩니다.
      =INDEX($B$5:$B$12,MATCH("노트류"&"스프링노트",$C$5:$C$12&$D$5:$D$12,0),1)
      자세한 설명은 이 사이트의 "INDEX, MATCH를 이용한 다중조건으로 값찾기"글을 참고하세요.
      https://xlworks.net/findingvalue-using-index-match/

  9. 아!!모야

    홀 4 5 6 13 14 15
    파 3 4 5 3 5 4 파 보기 더블보기
    김성식 4 3 5 4 7 5
    오동훈 3 4 6 3 6 6
    조성호 6 4 7 2 5 5

    골프의 경우 파3 파4 파5 처럼 기준이 다른 경우 함수값 지정은 어떻게 하나요?
    (갯수 함수입니다)

    1. 올려주신 내용으로는 정확히 어떤 것을 원하시는지 파악하기가 어렵네요. 제가 골프를 모르기도 하고요.

  10. 난나야

    안녕하세요?
    =COUNTIFS(Sheet2!B:B,"1",Sheet2!C:C,"1",Sheet2!J:M,"1") 이란 함수로 만들었는데요,
    영역이 되는 기준이 '1열,1열,영역'으로는 설정이 안되는건지 문의 드립니다....

    1. COUNTIFS함수의 인수로 들어가는 범위는 전부 같은 구조이어야 합니다. 앞의 2개의 범위는 1개의 열을 참조하는데 마지막 인수범위 J:M열을 참조하는 구조는 불가능합니다. 대신 다음과 같이 배열수식을 사용해 보세요. 그런데 J:M열에 같은 값이 같은 행에 모두 포함되어 있으면 원하는 결과보다 갯수가 많이 나옵니다. =SUMPRODUCT((B:B="1")*(C:C="1")*(J:M="1")) 입력후 Ctrl+Shift+Enter를 눌러야 합니다.

  11. 혹시 4) 다른 시트의 자료를 참조하여 참석자 수 집계 << 이거에서
    사람 수를 집계 하는게 아니라 김회계가 총 3번 이상 교육을 들었을 때 색상이 표기 되도록 하는
    방법도 알 수 있을까요? 물론 조건부서식이 필요하겠지만 조건부서식에 작성 해야 하는 함수와 방법이 궁금합니다.

  12. 휴무카운트

    =COUNTIFS(L4:L13,"휴무",L4:L13,"연차")

    한 범위에서 두가지 조건을 충족시킬경우 갯수새는방법은 없을까요 ?
    위처럼 했더니 안되네요 ㅎㅎ

    1. 안녕하세요. 위와 같이하면 휴무이면서 동시에 연차를 내는 사람을 count하므로 논리적으로 맞지 않습니다.
      휴무 또는 연차를 낸 사람을 구해야 하는데 다음과 같이 입력하면 됩니다.
      =COUNTIFS(L4:L13,"휴무") + COUNTIFS(L4:L13,"연차")

  13. 송예원

    100~110 사이의 숫자가 있으면 세라 라는 것을 어떻게 표현할 수 있을가요?
    1번 : 100
    2번 : 101
    3번 : 109
    -> 총 3개
    -> 이렇게 범위의 값이 있을 경우 세도록이요!

    1. [A1:A10] 범위에 숫자가 있을 때 다음과 같이 입력하세요(100보다 크거나 같고 110보다 작거나 같은)
      =COUNTIFS(A1:A10,">=100",A1:A10,"<=110")

  14. 엑셀은어렵다

    A B C D E F
    1 바닥 바닥 벽체 바닥 벽체 바닥
    2 70 40 80 60 90 100
    3 40 30 70 30 50 60
    4 30 20 50 20 30 40

    전체에서 바닥 30에 해당 되는게 몇 개인지 찾고 싶습니다.
    =COUNTIF(IF(A1:F1="바닥",OFFSET(INDEX(A1:F1,MATCH("바닥",A1:F1,0)),3,0),""),30)
    이렇게 했는데 값이 1이 나옵니다.

    혹시 제 머리로는 어떻게 풀어야할지 도저히 모르겠는데.. 도움좀 받을수 있을까요?

  15. 엑셀은어렵다

    감사합니다!!덕분에 해결했습니다. 천천히 읽어보고 잘 배우겠습니다. 시간 내주셔서 감사합니다.

  16. 스돕자

    4) 다른 시트 자료 집계하기(교육참석현황 집계)
    [F47] 셀 : =COUNTIFS(교육참석현황!$A$2:$A$22,집계!B47,교육참석현황!$C$2:$C$22,집계!C47) 에서 2번째, 4번째 있는 인수는 같은 시트의 셀을 참조하는데, 시트명을 써야 하는 이유가 있을까요? 시트명 쓰지 않고 그냥 B47, C47이라고 입력해도 정상 기능하는 것 같아서요.

    1. 같은 시트의 셀을 참조할 때는 시트명을 안써도 됩니다. 다른 시트를 참조하는 수식을 쓸 때 알아보기 쉬우라고 같은 시트라도 시트명을 쓰는 경우가 있습니다.

  17. 이수지

    안녕하세요 혹시 같은 범위 내에서 여러가지 조건을 만족시키는 셀의 개수를 구하는 방법은 없을까요??
    드롭다운 4개 중 3개에 해당되는 셀의 개수 구하기 이런거요..ㅠㅠ

    1. A1:A10 범위에 값이 있다고 하고 이 범위에 있는 A 또는 B의 갯수를 구하는 경우로 이해됩니다.
      다음 수식을 입력하시면 됩니다.
      =COUNTIF(A1:A10,"A")+COUNTIF(A1:A10,"B")
      또는 다음 수식을 사용해도 됩니다.
      =SUMPRODUCT((COUNTIF(A1:A10,{"A","B"})))

  18. 안녕하세요

    -0.5 =< O7:O31 ="&$L7,O7:O31,"<="&$M7)
    다음과 같은 수식을 짜서 조건의 셀에서 L,M만 절대참조를 주어 23,24에서는 다른 조건 값을 적용시켜 카운트를 하려고 했습니다.
    하지만 -0.5~0.5의 조건으로만 카운트 됐습니다.

    어떤 오류가 있고, 원하는 수식을 만드려고 하면 어떻게 해야할까요?

    1. 글 수정이 안되네요.
      댓글로 다시 올리겠습니다

      안녕하세요

      -0.5 =< O7:O31 ="&$L7,O7:O31,"<="&$M7)
      다음과 같은 수식을 짜서 조건의 셀에서 L,M만 절대참조를 주어 23,24에서는 다른 조건 값을 적용시켜 카운트를 하려고 했습니다.
      하지만 -0.5~0.5의 조건으로만 카운트 됐습니다.

      어떤 오류가 있고 원하는 수식을 만드려고 하면 어떻게 해야할까요?

      1. 안녕하세요

        -0.5 =< O7:O31 <= -0.5 조건을 만족하는 셀의 개수를 파악하려고 합니다.
        여기서 L7:L31 은 -0.5 (L23, L24는 -1.0)
        M7:M31 은 0.5 (M23, M24는 0)

  19. 그리하여,
    =COUNTIFS(O7:O31,">="&$L7,O7:O31,"<="&$M7)
    다음과 같은 수식을 짜서 조건의 셀에서 L,M만 절대참조를 주어 23,24에서는 다른 조건 값을 적용시켜 카운트를 하려고 했습니다.
    하지만 -0.5~0.5의 조건으로만 카운트 됐습니다.

    어떤 오류가 있고 원하는 수식을 만드려고 하면 어떻게 해야할까요?

    1. =COUNTIFS(O7:O22,">="&$L$7,O7:O22,"="&$L$23,O23:O24,"="&$L$7,O25:O31,"<="&$M$7)
      이런식으로도 한 수식에 구간을 나눠서 짜봤는데 #VALUE! 오류가 뜨네요..

  20. 손진희

    A1:A10 범위에 값이 있다고 하고 이 범위에 있는 / 또는 /*의 갯수를 구하는 경우
    =COUNTIF(A1:A10,"/")+COUNTIF(A1:A10,"/*")
    수식으로 적용했더니 COUNTIF(A1:A10,"/") 갯수가 2개로 표시되는데
    =COUNTIF(A1:A10,"/"-1)+COUNTIF(A1:A10,"/*")
    제 임의로 -1를 넣었더니 1개의 갯수로 표시가 됩니다.
    왜 2개로 표시 되는걸까요?

    1. A1:A10 범위에 어떤 값이 있는 모르기 때문에 답변이 정확하지 않을 수 있지만...
      /*에서 *은 와일드카드입니다. 그래서 /*의 갯수를 세는 것이 아니라 /로 시작하는 아무것이나 다 셉니다.
      두번째 COUNTIF(A1:A10,"/"-1) 이 수식은 아무런 의미가 없는 오류가 발생하는 수식입니다. 그래서 결과는 0이고 COUNTIF(A1:A10,"/*")의 갯수 1만 나옵니다.
      정확한 결과를 원하시면 A1:A10 범위에 입력된 값을 알려주세요.

      와일드카드는 다음 링크 참고하세요.
      https://xlworks.net/excel-wildcard/

댓글 남기기

Scroll to Top