12강 – VBA로 Access DB에 연결하여 Data처리하기(ADO를 이용하여 Data삭제)

12강에서는 VBA로 Access DB에 연결하여 Data를 삭제하는 작업을 해 보고자 한다.

6강에서는 Excel의 Sheet를 Database처럼 사용하여 Data를 삭제해 보았는데 이번 강에는 Excel Sheet대신에 Access를 Database로 사용하여 아래와 같이 구현해 본다. 따라서 DB연결 및 Data삭제 부분을 제외하고는 6강과 내용이 거의 동일하다.

1. 삭제버튼 클릭시 Event처리

Data를 삭제하기 위해서는 삭제하려는 Data가 폼에 조회되어 있어야 한다. 조회된 Data에 해당하는 Data를 Access DB에서 삭제하는 것이다. 위 폼의 "삭제"버튼을 누르면 Data가 삭제되도록 "삭제"버튼의 Click Event에 다음의 코드를 입력한다. 삭제 버튼을 누르면 deleteUser function을 call하여 Data를 삭제한다.

Private Sub cmdDelete_Click()

Dim argUser As User
Dim result As JobResult
    
    If Me.txtId.Value = "" Then
        MsgBox "조회 후 삭제하세요."
        Exit Sub
    End If
    
    argUser.id = CLng(Me.txtId.Value)
    
    '//삭제처리하고 결과값을 받는다.
    result = deleteUser(argUser:=argUser)

    
    '//처리 후 결과코드로 정상처리 여부를 판단한다.
    If result.code = 0 Then
        MsgBox result.message
    Else
        MsgBox "작업중 에러가 발생했습니다. 아래의 메시지를 확인바랍니다." & vbNewLine & vbNewLine & result.message
    End If
    
    '//처리후 변경된 내용을 조회하여 Form에 반영한다.
    loadUserToForm
    

End Sub

 

2. Access DB에 있는 Data삭제(Delete)하기

아래는 Data를 삭제하는 deleteUser Function이다. 삭제버튼을 누르면 이 Function이 실행되어 Data가 삭제(Delete)된다. modUser module에 붙여 넣는다.

Function deleteUser(argUser As User) As JobResult
    
Dim dbConn As New ADODB.Connection
Dim result As JobResult
Dim affectedCount As Long
Dim strSQL As String
Dim strConn As String

'//Access를 Database로 사용할때는 Delete문 사용이 가능하므로 기존로직은 삭제한다
'//기존 로직이 궁금하면 6강의 실습파일 참고바람.

On Error GoTo ErrHandler


    strSQL = "DELETE FROM [사원정보] " & _
             " WHERE [사번] = " & argUser.id
             
'//Access를 Database로 사용할때  Database연결문자열, Access DB명은 common module의 global변수 "gAccessDBName"에 지정한다.
    strConn = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & ThisWorkbook.Path & "\" & gAccessDBName & ";"

    dbConn.Open strConn
    dbConn.Execute CommandText:=strSQL, recordsaffected:=affectedCount
    
  
    If affectedCount = 0 Then
        result.code = -1
        result.message = "입력한 사번 해당하는 Data가 없어서 삭제되지 않았습니다."
    Else
        result.code = 0
        result.message = "처리되었습니다."
    End If
    
CommonEnd:
    
    deleteUser = result

    
Exit Function

'//에러처리
ErrHandler:

    If (Err.Number <> 0) Then
        result.code = Err.Number
        result.message = Err.Description
    End If
    
    Resume CommonEnd
    
End Function

위의 내용만으로 완전한 기능을 구현할 수 없다. Form에 추가된 textbox등은 이름이 위의 코드와 일치해야하고, 또 위에 언급되지 않은 부분이 있을 수 있으므로 자세한 내용은 첨부를 다운로드 받아서 확인해 보자.

첨부(실습용 파일) : 9강부터12강_VBA를_이용하여DB에Data추가_삭제(Access이용).zip
(압축파일을 풀면 xlsm, mdb파일이 보인다. xlsm파일은 매크로실행파일이고 mdb파일은 Access DB파일이다. mdb파일은 매크로실행파일과 동일한 폴더내에 있어야 한다)

 

[ 엑셀에서 Database사용하기 강좌 목록 ]

• 18강 - VBA로 MS SQL Server에 연결하여 Data처리하기(Stored Procedure로 조회)
• 17강 - VBA로 PostgreSQL에 연결하여 Data처리하기(ADO를 이용하여 조회,추가,수정,삭제)
• 16강 - VBA로 MariaDB에 연결하여 Data처리하기(ADO를 이용하여 조회,추가,수정,삭제)
• 15강 - VBA로 MySQL에 연결하여 Data처리하기(ADO를 이용하여 조회,추가,수정,삭제)
• 14강 - VBA로 Oracle DB Server에 연결하여 Data처리하기(ADO를 이용하여 조회,추가,수정,삭제)
• 13강 - VBA로 MS SQL Server에 연결하여 Data처리하기(ADO를 이용하여 조회,추가,수정,삭제)
• 12강 – VBA로 Access DB에 연결하여 Data처리하기(ADO를 이용하여 Data삭제)
• 11강 – VBA로 Access DB에 연결하여 Data처리하기(ADO를 이용하여 Data추가)
• 10강 – VBA로 Access DB에 연결하여 Data처리하기(ADO를 이용하여 Data조회 및 저장)
• 9강 – VBA로 Access DB에 연결하여 Data처리하기(ADO를 이용하여 연결, 조회)
• 8강 - VBA로 엑셀에서 Database 연결 및 처리를 위한 ADO이해
• 7강 – VBA로 엑셀에서 Database 연결, Data처리 기본개념
• 6강 – VBA로 엑셀Sheet에 연결하기(Data삭제-ADO이용안함)
• 5강 – VBA로 엑셀Sheet에 연결하기(ADO를 이용하여 Data추가)
• 4강 - VBA로 엑셀Sheet에 연결하기(ADO를 이용하여 조회 및 저장)
• 3강 - VBA로 엑셀Sheet에 연결하기(ADO를 이용하여 연결, 조회)
• 2강 - Microsoft Query를 이용하여 Database에 연결하기
• 1강 - 들어가기 - Database는 무엇인가, 왜 엑셀에서 Database를 다루는가?